技術資料

Novable Type のプラグインなどで、ユーザーの追加処理を行なう場合、 MT::Author オブジェクトを利用します。

※参考: Movable Type オブジェクト・リファレンス - MT::Author

以下のような感じ。

my $app = shift;
my $username = 'new_user'; # 追加したいユーザー名
my $displayname = 'new_user'; # 追加したいユーザーの表示名
my $email = 'newuser@abe-tatsuya.com'; # 追加したいユーザーのメールアドレス
my $password = 'abcdefghijklmn'; # 追加したいユーザーのパスワード

# ユーザーの存在確認
my $author = MT::Author->load({ name => $username });
if(!$author){
    # ユーザーが存在しない場合は新規作成
    eval{
        $author = MT::Author->new;
        $author->name($username);
        $author->nickname($displayname);
        $author->email($email);
        $author->auth_type('MT');
        $author->created_by(1);
        $author->set_password($password);
        $author->can_sign_in_cms(1);
        $author->save
            or die $author->errstr;
        # ユーザー作成をログに記録
        $app->log({
            message  => $app->translate(
                "User '[_1]' has been created.",
                $author->name
            ),
            level    => MT::Log::INFO(),
            class    => 'system',
            category => 'create_user'
        });
    };
    if($@){
        print "Content-Type: text/html\n\n";
        print "Error creating new user: $@";
        # ログにエラーメッセージを記録
        $app->log({
            message  => "Error creating new user: $@",
            level    => MT::Log::ERROR(),
            class    => 'system',
            category => 'create_user',
        });
        exit;
    }
}

上記のコードは、指定したユーザーを「ユーザー名」で検索し、存在しないければ追加する、という処理のコードです。

MT::Author->load({ name => $username })

ユーザー名で検索して、Authorオブジェクトを返します。
name の代わりに email や id でも検索できます。

MT::Author->new

新規に Author オブジェクトを生成します。

name($username)
nickname($displayname)
email($email)

ユーザーの「ユーザー名」「表示名」「メールアドレス」をセットします。

auth_type('MT')

MT管理画面へのログイン認証方法をセットします。MT をセットしないと、MTデフォルトのログインができません。

created_by(1)

このユーザーを作成したユーザーのIDをセットします。今回の例では、システム管理者(ID=1)によって作成されたことにします。

set_password($password)

暗号化されたパスワードをセットします。

can_sign_in_cms(1)

MT管理画面へのログイン権限をセットします。この権限がないとMTにログインできません。
他の権限は、

is_superuser

システム管理者

can_edit_templates

テンプレートの管理

can_manage_plugins

プラグインの管理

can_view_log

システムログの閲覧

can_sign_in_data_api

Data API でのサインイン

can_create_site

サイトの作成

can_manage_users_groups

ユーザーとグループの管理

can_manage_content_data

すべてのコンテンツデータの管理

can_manage_content_types

コンテンツタイプの管理

でセットできます。

save

Authorオブジェクトを保存します。