技術資料

Perlのデバックに便利な Data::Dumperの使い方メモ。

変数・配列・連想配列を出力

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dumper;
    
my $scholar = 'scholar';
my @array = ('array1','array2','array3');
my %hash = (
    'hash1' => 1,
    'hash2' => 2,
    'hash3' => 3
);

print Dumper $scholar;
print Dumper @array;
print Dumper %hash;

### 出力
$VAR1 = 'scholar';

$VAR1 = 'array1';
$VAR2 = 'array2';
$VAR3 = 'array3';

$VAR1 = 'hash1';
$VAR2 = 1;
$VAR3 = 'hash2';
$VAR4 = 2;
$VAR5 = 'hash3';
$VAR6 = 3;


print Dumper \@array;
print Dumper \%hash;

### 出力
$VAR1 = [
          'array1',
          'array2',
          'array3'
        ];
$VAR1 = {
          'hash1' => 1,
          'hash2' => 2,
          'hash3' => 3
        };

複雑なネストの変数を出力

my @array = (
    'array0',
    ['array1_1','array1_2','array1_3'],
    ['array2_1','array2_2',
        ['array2_3_1','array2_3_2','array2_3_3']
    ]
);

print Dumper \@array;

### 出力
$VAR1 = [
          'array0',
          [
            'array1_1',
            'array1_2',
            'array1_3'
          ],
          [
            'array2_1',
            'array2_2',
            [
              'array2_3_1',
              'array2_3_2',
              'array2_3_3'
            ]
          ]
        ];

my $data = {
    'name' => 'tatsuya',
    'age' => 48,
    'favorite' => [
        '古生物',
        '将棋',
        "B'z"
    ],
    'reading' => {
        'SF' => '法治の獣',
        'Horror' => '屍鬼',
        'Fantasy' => '十二国記',
        'Mystery' => '荊の城'
    }
};

print Dumper $data;

### 出力
$VAR1 = {
    'reading' => {
                   'Horror' => '屍鬼',
                   'Fantasy' => '十二国記',
                   'Mystery' => '荊の城',
                   'SF' => '法治の獣'
                 },
    'name' => 'tatsuya',
    'favorite' => [
                    '古生物',
                    '将棋',
                    'B\'z'
                  ],
    'age' => 48
  };

ネストしたハッシュのリストを出力

my @users = (
    {
        id       => 1,
        name     => '御堂綱紀',
        contact  => {
            email => 'tsunanori@example.com',
            phone => '090-1234-5678',
        },
        roles    => ['admin', 'editor'],
    },
    {
        id       => 2,
        name     => 'アメイヤ・アシュリン',
        contact  => {
            email => 'ameya@example.com',
            phone => '080-8765-4321',
        },
        roles    => ['viewer'],
    },
);

print Dumper \@users;


### 出力
$VAR1 = [
          {
            'roles' => [
                         'admin',
                         'editor'
                       ],
            'id' => 1,
            'contact' => {
                           'phone' => '090-1234-5678',
                           'email' => 'tsunanori@example.com'
                         },
            'name' => '御堂綱紀'
          },
          {
            'contact' => {
                           'phone' => '080-8765-4321',
                           'email' => 'ameya@example.com'
                         },
            'name' => 'アメイヤ・アシュリン',
            'id' => 2,
            'roles' => [
                         'viewer'
                       ]
          }
        ];

配列のキーをソートして出力

$Data::Dumper::Sortkeys = 1;
print Dumper \@users;

### 出力
$VAR1 = [
          {
            'contact' => {
                           'email' => 'tsunanori@example.com',
                           'phone' => '090-1234-5678'
                         },
            'id' => 1,
            'name' => '御堂綱紀',
            'roles' => [
                         'admin',
                         'editor'
                       ]
          },
          {
            'contact' => {
                           'email' => 'ameya@example.com',
                           'phone' => '080-8765-4321'
                         },
            'id' => 2,
            'name' => 'アメイヤ・アシュリン',
            'roles' => [
                         'viewer'
                       ]
          }
        ];

インデントのスタイル変更

$Data::Dumper::Indent で設定可能。

perldoc.jpによると、

インデントのスタイルを制御します。0, 1, 2, 3を指定できます。スタイル0はリストの 項目間に改行、インデント、スペースを一切含めずに出力します。もっともコンパクトな形式ですが、 perlとして実行可能です。スタイル1は改行ありで読みやすい形ですが、見やすいインデントが ありません（それぞれの構造におけるレベルは、単に固定長のスペースでインデントされています）。 スタイル2（デフォルト）はとても読みやすい形式で、ハッシュキーが揃っています。 スタイル3はスタイル2に似ていますが、配列の要素にインデックス数が付記されます（ただし、 付記は独立した行なので、配列の出力は２倍の行を消費します）。スタイル2がデフォルトです。

とのこと。

$Data::Dumper::Indent = 0;
print Dumper \@users;
    
### 出力
$VAR1 = [{'contact' => {'phone' => '090-1234-5678','email' => 'tsunanori@example.com'},'roles' => ['admin','editor'],'id' => 1,'name' => '御堂綱紀'},{'roles' => ['viewer'],'contact' => {'phone' => '080-8765-4321','email' => 'ameya@example.com'},'name' => 'アメイヤ・アシュリン','id' => 2}];


$Data::Dumper::Indent = 1;
print Dumper \@users;

### 出力
$VAR1 = [
  {
    'name' => '御堂綱紀',
    'roles' => [
      'admin',
      'editor'
    ],
    'contact' => {
      'email' => 'tsunanori@example.com',
      'phone' => '090-1234-5678'
    },
    'id' => 1
  },
  {
    'contact' => {
      'phone' => '080-8765-4321',
      'email' => 'ameya@example.com'
    },
    'id' => 2,
    'name' => 'アメイヤ・アシュリン',
    'roles' => [
      'viewer'
    ]
  }
];


$Data::Dumper::Indent = 2;
print Dumper \@users;

### 出力
$VAR1 = [
          {
            'roles' => [
                         'admin',
                         'editor'
                       ],
            'name' => '御堂綱紀',
            'contact' => {
                           'phone' => '090-1234-5678',
                           'email' => 'tsunanori@example.com'
                         },
            'id' => 1
          },
          {
            'name' => 'アメイヤ・アシュリン',
            'id' => 2,
            'contact' => {
                           'email' => 'ameya@example.com',
                           'phone' => '080-8765-4321'
                         },
            'roles' => [
                         'viewer'
                       ]
          }
        ];


$Data::Dumper::Indent = 3;
print Dumper \@users;

### 出力
$VAR1 = [
          #0
          {
            'id' => 1,
            'roles' => [
                         #0
                         'admin',
                         #1
                         'editor'
                       ],
            'name' => '御堂綱紀',
            'contact' => {
                           'phone' => '090-1234-5678',
                           'email' => 'tsunanori@example.com'
                         }
          },
          #1
          {
            'name' => 'アメイヤ・アシュリン',
            'id' => 2,
            'roles' => [
                         #0
                         'viewer'
                       ],
            'contact' => {
                           'phone' => '080-8765-4321',
                           'email' => 'ameya@example.com'
                         }
          }
        ];